SAS忘備録: 9月 2019

2019年9月29日日曜日

ODS LAYOUT GRIDDED入門: 基本構文

SAS9.4から追加された「ODS LAYOUT GRIDDED」では格子状に領域を作って、プロシジャの出力を各領域に配置させることが出来ます。

格子状に仕切りを定義するODS LAYOUT GRIDDEDのイメージ

構文

ODS LAYOUT GRIDDED オプション;

ODS REGION;
プロシジャ

ODS REGION;
プロシジャ

ODS LAYOUT END;

「ODS HTML」「ODS PRINTER (PDF等)」「ODS PowerPoint」への出力のみサポート。
「ODS REGION」で次の領域に移動します。
「ODS LAYOUT GRIDDED」には以下のオプションが設定可

オプション

指定	設定内容
width = height =	レイアウトの幅レイアウトの高さ
columns = rows =	列数行数
column_gutter = row_gutter =	列間のスペースの横幅行間のスペースの高さ
order_type = row_major \| column_major	次の領域に進む順を縦方向にするか横方向にするか
column_widths = ( 幅1, 幅2・・・) row_heights = ( 高さ1, 高さ2・・・)	各列の幅各行の高さ
x = y =	レイアウトの横位置レイアウトの縦位置
advance = bygroup \| explicit \| proc \| table \| output	(ODS REGION以外で) 次の領域に移動するルール (別記事で解説)
description = "テキスト"	代替テキスト
style = [スタイル]	レイアウトのスタイル

例

ods pdf file="c:\test.pdf";

ods layout gridded
columns=2 rows=2 column_gutter=0in row_gutter=0in;

ods region;
proc freq data=sashelp.class;
tables sex;
run;

ods region;
proc means data=sashelp.class n mean std;
var height weight;
run;

ods region;
ods graphics / width=3in height=2in;
proc sgplot data=sashelp.class;
scatter x=height y=weight / group=sex;
run;

ods layout end;

ods pdf close;

記事一覧

1. 基本構文

2. ODS REGION

2019年9月23日月曜日

PROC ODSTEXT入門: 書式の設定

以下のテキスト出力ステートメントでは「STYLEオプション」でテキストの書式を設定できます。

P
ITEM
HEADING

構文

P "テキスト" / STYLE = [ 書式 ] ;

書式

指定	設定内容	例
FONTFAMILY	フォント	fontfamily='ＭＳＰ明朝'
FONTSIZE	文字サイズ	fontsize=10pt
FONTWEIGHT	文字の太さ	fontweight=bold
FONTSTYLE	斜体等のスタイル	fontstyle=roman
COLOR	文字色	color = blue
BACKGROUNDCOLOR	セル色	backgroundcolor = yellow
・・・など

例

proc odstext;
h1 "食欲の秋" / style=[color=yellow fontsize=20pt];
p "栗" / style=[color=brown fontsize=50pt];
p "柿" / style=[color=orange fontsize=20pt];
run;

また、条件によって書式を設定したい場合「CELLSTYLE-ASステートメント」が使えます。

構文

CELLSTYLE 条件1 AS { 書式1 },
条件2 AS { 書式2 },
条件3 AS { 書式3 },
・・・
;

例

proc odstext data=sashelp.class;
list;
cellstyle age=12 as {color=orange},
age=13 as {color=red};
item strip(put(age,best16.)) || ", " || name;
end;
run;

上の例では、

「AGE=12」だったら「文字色をOrange」に
「AGE=13」だったら「文字色をRed」に
それ以外は書式指定なし

としています。

記事一覧

1. 基本構文

2. リストの入れ子

3. 見出しの設定
4. 書式の設定

2019年9月19日木曜日

PROC ODSTEXT入門: 見出しの設定

（SAS9.4M4からの新機能です）

HTMLとか触ったことある方ならピンときやすいですが、「HEADINGステートメント」で「見出し」を設定できます。

構文

H1 "見出しにするテキスト";

「H1」～「H6」で見出しレベルを設定できます。

例

proc odstext;
h1 "食欲の秋";
p "栗";
p "柿";
p "さつまいも";
run;

見出しって大切です。
何が大切かってのはまた今度紹介できたらと思います。

記事一覧

1. 基本構文

2. リストの入れ子

3. 見出しの設定

4. 書式の設定

2019年9月11日水曜日

ODS EXCELでセル書式を設定する

PROC REPORTなどで使える「STYLE=オプション」で書式を設定することができますが、ODS EXCELで使うと、EXCELのセル書式を設定できてしまいます。

「STYLE=オプション」の詳細は過去記事をご覧ください。
https://sas-boubi.blogspot.com/2016/02/report8.html

例

ods excel file='c:\test.xlsx';

proc report data=sashelp.class missing style( header ) = [ background=blue color=white ];
column sex name age height weight;
define sex / order order=internal;
compute weight;
if age.sum > 12 then do;
call define( "age.sum", "style", "style = [ color=red ]" );
call define( "name" , "style", "style = [ background=yellow ]" );
end;
endcomp;
run;

ods excel close;