SAS忘備録: -

2014年9月29日月曜日

変数名をいっきに指定する方法 [まとめ]

変数名を省略する便利な書き方をまとめます。

*** サンプルデータ ;
data DT1;
A1 = 1;
A2 = 1;
A3 = 1;
B = "abc";
C = 2;
run;

*** A1～A3まで連番になってる変数 ;
data DT2;
set DT1;
keep A1 - A3; /* 「keep A3 - A1」と逆にしてもok */
run;

*** 変数名がAで始まる変数 ;
data DT3;
set DT1;
keep A: ;
run;

*** A3からCまで順番に格納されてる変数 ;
data DT4;
set DT1;
keep A3 -- C;
run;

*** A3からCまで順番に格納されてる変数の中での数値変数 ;
data DT5;
set DT1;
keep A3 -numeric- C;
run;

*** A3からCまで順番に格納されてる変数の中での文字変数 ;
data DT6;
set DT1;
keep A3 -character- C;
run;

*** 数値変数のみ ;
data DT6;
set DT1;
keep _numeric_;
run;

*** 文字変数のみ ;
data DT6;
set DT1;
keep _character_;
run;

*** 全変数 ;
data DT6;
set DT1;
keep _all_;
run;

今回はKEEPステートメントでの例でしたが、さまざまなステートメントで使えます。
気をつけなきゃいけないのは以下のように関数中に指定するケース。

× sum(A1-A3);
○ sum(of A1-A3);

「A1-A3」だと引き算の意味になってしまう！この場合は必ず「of」を先頭につけましょう。

あとは、変数の格納順をコロコロ変えるかもしれないデータセットに対して
「A3 -- C」、　「A3 -numeric- C」、　「A3 -character- C」といった省略文を書くのは避けましょう。

（変数の格納順が変わるたびに、この省略文を修正しなきゃいけなくなって、プログラムとして不安定になる）

2014年6月13日金曜日

変数指定は「V100-V1」のように逆にもできる。

変数がV1、V2・・・V100とあったとき、「keep V1-V100」みたいに範囲指定して書けることはわりと知られています。
これはさらに「keep V100-V1」のように逆に指定することもできます。

この逆指定で処理が楽になる例を以下にあげてみました。

サンプルデータのNO1からNO3の中で最後の値を取ってきたい場合、
COALESCE関数と変数逆指定の組み合わせで簡単に出来てしまいます。

*** サンプルデータ作成 ;
data DT1;
input SUBJID:$3. NO1 NO2 NO3;
cards;
001 100 95 110
002 56 50 .
003 90 . .
;

*** 変数の逆指定 ;
data DT2;
set DT1;
LAST = coalesce( of NO3-NO1 );
run;

SUBJID	NO1	NO2	NO3	LAST
001	100	95	110	110
002	56	50	.	50
003	90	.	.	90

変数の範囲指定を関数で行う場合「of」を先頭につけるのを忘れずに！