2019年4月16日火曜日

ODS EXCEL入門: シートの設定いろいろ






シートの設定に関する以下のオプションを紹介。

  • SHEET_INTERVAL
  • SHEET_NAME
  • TAB_COLOR




SHEET_INTERVAL … シートの分け方を設定
構文
ODS EXCEL OPTIONS( SHEET_INTERVAL = "シートの分け方" );


シートの分け方は以下が設定できます。

  指定     結果    
 BYGROUP

 プロシジャに指定したBYグループ毎にシートを分ける 

 PAGE

 プロシジャが改ページを入れるタイミングでシートも分ける （下の方に補足説明あり）

 PROC

 		 プロシジャ毎にシートを分ける

 NONE

 シートを分けない(1シートに全て出力)

 NOW

 プロシジャの結果を新しいシートに出力する。出力後は前の設定に戻る（下の方に例あり）
※SAS9.4M5からの機能
 TABLE  

 プロシジャから出力される表毎にシートを分ける（デフォルトはこの設定）




2つ目の「PAGE」について補足
プロシジャの結果をHTMLに出力すると、以下の緑矢印で示した横線が入ることがありますよね。こっから次のページだよって意味になります。



こんな感じで、プロシジャがページを分けるタイミングでシートも分けるってのが「sheet_interval="page"」です・・・これ見てもよく分かんないと思うんで色々試して確認してみてください。




例1.
proc sort data=sashelp.class out=class;
    by sex;
run;

ods excel file="出力先パス\test.xlsx" options( sheet_interval="bygroup" );

    proc means data=class;
        var height;
        by sex;
    run;

ods excel close;


「sheet_interval="bygroup"」でBY変数SEXの出力結果毎にシートを分けています。




例2.
proc sort data=sashelp.class out=class;
    by sex;
run;

ods excel file="出力先パス\test2.xlsx" options( sheet_interval="none" );

    proc means data=class;
        var height;
        by sex;
    run;

ods excel options( sheet_interval="now" );

    proc means data=class;
        var weight;
        by sex;
    run;

ods excel close;


まず「sheet_interval="none"」で最初のプロシジャの結果をすべて1シートに出力してます。
次に「sheet_interval="now"」で新しいシートを作成して、次のプロシジャの結果をすべてそのシートに出力してます。




SHEET_NAME … シート名の設定
構文
ODS EXCEL OPTIONS( SHEET_NAME = "シート名" );


例3.
proc sort data=sashelp.class out=class;
    by sex;
run;

ods excel file="出力先パス\test3.xlsx" options( sheet_interval="none" sheet_name="MySheet" );

    proc means data=class;
        var weight;
        by sex;
    run;

ods excel close;





TAB_COLOR … シートタブの色を設定する
構文
ODS EXCEL OPTIONS( TAB_COLOR = "色" );


例4.
proc sort data=sashelp.class out=class;
    by sex;
run;

ods excel file="出力先パス\test4.xlsx" options( tab_color="yellow" );

    proc means data=class;
        var weight;
        by sex;
    run;

ods excel close;





ODS EXCEL入門記事一覧

注意点

ラベル:

0 件のコメント:

コメントを投稿

登録: コメントの投稿 (Atom)