2015年5月12日火曜日

RWIでフォトブックをつくる


SAS9.2ではちゃんとした結果が出てくれないかも。

(また、貼り付ける画像ファイルによっては、出来上がるファイル容量も馬鹿でかくなるので、実行環境のPCに自信がない場合は、実行しない方がいいかも)

プログラムを実行する場合は、プログラム中の青字にしてるパスを各時環境のパスに変更してください。
あとSAS9.3の場合は、「style_attr」の部分をすべて「overrides」に変えてください。

プログラムで使う写真

   



プログラム
ods html close;
ods pdf file="/folders/myfolders/photobook.pdf" notoc  dpi=150;

data _NULL_;
  dcl odsout ob();

  *** 1ページ目 ***************************;
  ob.layout_absolute();

    * 1枚目の写真 ;
    ob.region( x:'2cm',  y:'1cm',  width:'9cm' );
    ob.image( file:'/folders/myfolders/DSC_0614.jpg' );

    ob.region( x:'12cm',  y:'5cm',  width:'7cm' );
    ob.format_text( data:"夏の恒例「SASユーザー総会」",
                         style_attr:"fontsize=12pt" );

    * 2枚目の写真 ;  
    ob.region( x:'10cm',  y:'12cm',  width:'8cm');
    ob.image( file:'/folders/myfolders/DSC_0618.jpg' );

    ob.region( x:'2cm', y:'22cm', width:'8cm' );
    ob.format_text( data:"ユーザー総会限定の粗品",
                         style_attr:"fontsize=12pt" );
    
  ob.layout_end();

  ob.page();

  *** 2ページ目 ***************************;
  ob.layout_absolute();

    * 1枚目の写真 ;
    ob.region( x:'2cm', y:'1cm', width:'10cm' );
    ob.image( file:'/folders/myfolders/DSC_0489.jpg' );

    ob.region( x:'12.5cm', y:'5cm', width:'7cm' );
    ob.format_text( data:"堀切菖蒲園の菖蒲たち",
                         style_attr:"fontsize=12pt" );

    * 2枚目の写真 ;  
    ob.region( x:'2cm', y:'9cm', width:'10cm' );
    ob.image( file:'/folders/myfolders/DSC_0611.jpg' );

    ob.region( x:'12.5cm', y:'16cm', width:'7cm' );
    ob.format_text( data:"熱い将棋バトル、電王戦タッグマッチ2014",
                         style_attr:"fontsize=12pt" );
 
  ob.layout_end();

run;

ods pdf close;
ods html;


結果



プログラム2行目の「ods pdf  ~ dpi=150;」で、出力するPDFファイルの解像度を設定してます。

写真の解像度が高いと、出来上がるPDFファイルの容量も大きくなってしまいます。
デフォルトは 「dpi=150」なので、写真枚数が多い場合は、ファイル容量が恐ろしくやばくなるので、まずは「dpi=75」とかにして、様子を見たほうがいいです。

(今回の例でも、たった4枚の写真で4MBもいっちゃったので、実用的じゃないかな。。?)

今回使用してるRWIについては、以下の入門シリーズにまとめています。
レポート作成インターフェイス(RWI)入門1

0 件のコメント:

コメントを投稿